ODS SIOC Reference

This article outlines the mapping of ODS data to the SIOC ontology for the purpose of constructing SPARQL Queries against OpenLink Data Spaces ODS Data.

Note:

• To validate a particular SIOC RDF Data Set (in plain old RDF form), you can use the W3C RDF Validation Service
• You can actually create you own Data Spaces and then experiment with these queries by opening accounts at: http://demo.openlinksw.com/ods (for very temporary and volatile usage) or http://myopenlink.net:8890/ods (for less volatile usage)
• You can run most (if not all) of the queries with minimal modification using the following SPARQL Query Services: http://demo.openlinksw.com/sparql/ (using the 'demo' user account) and http://myopenlink.net:8890/sparql/ (assuming you have an account with this service)
• Default Graph URI value used in the queries below is: http://demo.openlinksw.com/dataspace

Weblog Data Space

ODS-Weblog and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:Weblog
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:Weblog
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/weblog/myblog#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * attachment
   * content
   * has_container
   * has_creator
   * has_reply
   * id
   * link
   * links_to
   * reply_of
   * topic (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where 
  {
    ?forum a sioct:Weblog .
    ?forum sioc:container_of ?post .
    ?post ?attribute ?o  
  }
order by ?attribute

Dump of all Weblog Posts for a given ODS Member

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select DISTINCT ?forum_name, ?post, ?title ?cr ?url 
where    
  { 
    ?forum a sioct:Weblog .
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role. 
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post. 
    optional{?post dct:title ?title}.
    optional{?post dcc:created ?cr}.
    optional{?post sioc:link ?url}.
  }
order by DESC (?cr)

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of blog posts for user demo.

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Weblog Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp, ?proto 
where 
  {
    ?forum a sioct:Weblog .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of blog posts.

Dump of all Weblog Posts for a given ODS Member that includes content of blog post.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
prefix sioct: <http://rdfs.org/sioc/types#>
select ?forum_name, ?post, ?title, ?cr, ?content, ?url
where    
  { 
    ?forum a sioct:Weblog .
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role. 
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post. 
    optional{?post dct:title ?title }.
    optional{?post dcc:created ?cr }.
    optional{?post sioc:link ?url }.
    optional{?post sioc:links_to ?links_to }.
    optional{?post sioc:content ?content}
  } 

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of blog posts.

Dump of all Weblog Posts for a given ODS Member that includes content of blog post plus out-bound links.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select ?forum_name, ?post, ?title, ?cr, ?content, ?url, ?links_to
where    
   { 
     ?forum a sioct:Weblog . 
     ?forum sioc:id ?forum_name.
     ?forum sioc:scope_of ?role. 
     ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
     ?forum sioc:container_of ?post. 
     optional{ ?post dct:title ?title }.
     optional{ ?post dcc:created ?cr }.
     optional{ ?post sioc:link ?url }.
     optional{ ?post sioc:links_to ?links_to }.
     optional{?post sioc:content ?content}
   } 

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of blog posts.

Wiki Data Space

ODS-Wiki and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:Wiki
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:Wiki
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/wiki/mywiki#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * attachment
   * content
   * has_container
   * has_creator
   * id
   * link
   * links_to
   * reply_of (TBD - for older db is not supported)
   * topic (tags)
   * has_reply 

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where
   {
     ?forum rdf:type sioct:Wiki  .
     ?forum sioc:container_of ?post .
     ?post ?attribute ?o  
   }
order by ?attribute

Dump of all Wikiwords for a given Wiki

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select distinct ?forum_name, ?post, ?title, ?link, ?links_to, ?cr
where 
  {
    ?forum rdf:type sioct:Wiki .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post  dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional  {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .   
  }
order by ?title

Dump of all WikiWords for a given Wiki including content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select ?forum_name, ?post, ?title, ?link, ?cr, ?content
where 
  {
    ?forum rdf:type sioct:Wiki .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post  dct:title ?title.
    optional  {?post dcc:created ?cr}.
    optional  {?post sioc:link ?link} .
    optional  {?post sioc:content ?content}. 
  }

Dump of all WikiWords for a given Wiki including content plus out-bound links

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
where 
  {
    ?forum rdf:type sioct:Wiki .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .  
    optional {?post sioc:content ?content}. 
  }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a Collection of Wikis.

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Wiki Data Space Instances

prefix svc: <http://rdfs.org/sioc/services#>
prefix  sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto 
where
  {
    ?forum a sioct:Wiki.
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of Wiki Services.

Calendar Data Space

ODS-Calendar and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:Calendar
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:Calendar
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/calendar/mycalendar#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_creator
   * id
   * link
   * topic (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where 
  {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:container_of ?post .
    ?post ?attribute ?o  
  }
order by ?attribute

Dump of all Events for a given Calendar

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix calr: <http://www.w3.org/2002/12/cal#> 
select distinct ?forum_name, ?post, ?title, ?link, ?cr
where 
  {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    ?post  dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .   
  }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a Collection of Calendar Posts.

Dump of all Events for a given Calendar including content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
prefix calr: <http://www.w3.org/2002/12/cal#> 
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
where 
  {
    ?forum rdf:type sioct:Calendar.
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    optional {?post dct:title ?title}.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .  
    optional {?post sioc:content ?content}. 
  }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a Collection of Calendar Events.

Dump of Events with details for a given Calendar

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix calr: <http://www.w3.org/2002/12/cal#> 
select distinct ?forum_name, ?post, ?url, ?summary, ?descr, ?location
where 
  {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    optional{?post dct:title ?title}.
    optional{?post calr:url ?url }.
    optional{?post calr:summary ?summary }.
    optional{?post calr:description ?descr }.
    optional{?post calr:dtstart ?start}.
    optional{?post calr:location ?location}.
  }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a Collection of Calendar Events.

Feeds / Subscriptions Data Space (Feed Aggregation)

ODS-Feed Manager and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:SubscriptionList
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:SubscriptionList
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/subscriptions/DemoFeeds#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_creator
   * has_reply 
   * id
   * link
   * links_to   
   * reply_of
   * topic (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum rdf:type sioct:SubscriptionList .
        ?forum sioc:parent_of ?parentf .
        ?parentf sioc:container_of ?post .
        ?post ?attribute ?o  
      }
order by ?attribute

Obtaining a dump of all Posts within an ODS-Feeds Data Space.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc:  <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select  ?forum_name, ?channel, ?item_title, ?created
where 
  {
    ?forum a sioct:SubscriptionList;
                   sioc:id ?forum_name.
    ?forum sioc:scope_of ?role. 
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:parent_of ?channel .
    ?channel sioc:container_of ?post .
    optional{ ?post dct:title ?item_title }.
    optional{ ?post dcc:created ?created }.
  }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of Feed Subscriptions.

Obtaining a dump of all Posts within an ODS-Feeds Data Space that includes feed content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select  ?forum_name, ?channel, ?item_title, ?url, ?created, ?content
where 
  {
    ?forum a sioct:SubscriptionList;
               sioc:id ?forum_name.
    ?forum sioc:scope_of ?role. 
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:parent_of ?channel .
    ?channel sioc:container_of ?post .
    optional{ ?post dct:title ?item_title }.
    optional{ ?post sioc:links_to ?url }.
    optional{ ?post dcc:created ?created }.
    optional{ ?post sioc:content ?content}.
  }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of Feed Subscriptions.

Bookmarks Data Space

ODS-Bookmark Manager and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:BookmarkFolder
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:BookmarkFolder
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/bookmark/mybookmarks#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content   
   * has_container
   * has_creator
   * id
   * link
   * links_to
   * topic (tags) 

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum a sioct:BookmarkFolder .
        ?forum sioc:container_of ?post .
        ?post ?attribute ?o  
      }
order by ?attribute

Dump of all Bookmark Data Space entries for a given ODS Bookmarks Data Space

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
select distinct ?forum_name, ?post, ?title, ?link, ?url
where {
        ?forum a sioct:BookmarkFolder .
        ?forum sioc:id ?forum_name.
        ?forum sioc:scope_of ?role. 
        ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
        ?forum sioc:container_of ?post .
        optional{ ?post  dct:title ?title }.
        optional{ ?post sioc:link ?link  } .
        optional{ ?post sioc:links_to ?url }
      }
order by ?title

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of published bookmarks.

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Bookmarks Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto 
where 
  {
    ?forum a sioct:BookmarkFolder .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of Bookmarks Web Services..

AddressBook Data Space

ODS-AddressBook and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:AddressBook
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:AddressBook
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/addressbook/myAddressBook#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * has_container
   * has_creator
   * id
   * link
   * topic

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where
  {
    ?forum a sioct:AddressBook .
    ?forum sioc:container_of ?post .
    ?post ?attribute ?o  
  }
order by ?attribute

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of AddressBook Properties list .

Dump all properties supported for members imported from Briefcase FOAF uploaded

prefix sioct: <http://rdfs.org/sioc/types#>
prefix sioc: <http://rdfs.org/sioc/ns#>
select distinct ?attribute
where
  {
    ?s a sioct:AddressBook;
    sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member ?attribute ?o  
  }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of AddressBook contact list .

Dump all AddressBook's members

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select ?member, ?id
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?s a sioct:AddressBook;
    sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member sioc:id ?id.
   } 

Dump all AddressBook's members friends

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select ?member, ?knows
where
  {
    ?s a sioct:AddressBook;
       sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member foaf:knows ?knows
  }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of AddressBook contact list .

Dump all AddressBook's contacts

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix vcd: <http://www.w3.org/2001/vcard-rdf/3.0#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?FN ?nick ?address ?title ?created ?link ?topic 
where
  {
    ?forum a sioct:AddressBook .
    ?forum sioc:container_of ?post .
    optional {?post vcd:FN ?FN }.
    optional {?post vcd:NICKNAME ?nick}.
    optional {?post vcd:ADR ?address}.
    optional {?post dct:title ?title}.
    optional {?post dcc:created ?created}.
    optional {?post sioc:link ?link }.
    optional {?post sioc:topic ?topic } .
  }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of AddressBook contact list .

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with AddressBook Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto 
where 
  {
    ?forum a sioct:AddressBook .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of AddressBook Web Services.

Polls Data Space

ODS-Polls and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:SurveyCollection
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:SurveyCollection
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/polls/mypolls#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_creator
   * id
   * link
   * topic (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum a sioct:SurveyCollection.
        ?forum sioc:container_of ?post .
        ?post ?attribute ?o  
      }
order by ?attribute

Dump of all Polls Posts for a given ODS Member

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select DISTINCT ?forum_name, ?post, ?title ?cr ?url 
where    { 
           ?forum a sioct:SurveyCollection.
           ?forum sioc:id ?forum_name.
           ?forum sioc:scope_of ?role. 
           ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
           ?forum sioc:container_of ?post. 
           optional{ ?post dct:title ?title }.
           optional{ ?post dcc:created ?cr }.
           optional{ ?post sioc:link ?url }.
         }
order by DESC (?cr)

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of polls.

Photo Gallery Data Space

ODS-Photo Galleryand SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:ImageGallery
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:ImageGallery
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/photos/MyGallery#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_creator
   * id
   * link
   * topic (tags)
   * links_to (TBD)
   * reply_of (TBD)
   * has_reply (TBD)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum rdf:type sioct:ImageGallery .
        ?forum sioc:container_of ?post .
        ?post ?attribute ?o  
      }
order by ?attribute

Dump of all Data Space entries for a given ODS Photo Gallery including content.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select ?forum_name, ?post, ?title, ?link, ?cr, ?content
where {
        ?forum rdf:type sioct:ImageGallery .
        ?forum sioc:id ?forum_name.
        ?forum sioc:container_of ?post .
        optional {?post  dct:title ?title }.
        optional {?post dcc:created ?cr}.
        optional {?post sioc:link ?link} .
        optional {?post sioc:content ?content}
      }

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Gallery Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto 
where {
        ?forum a sioct:ImageGallery  .
        ?forum svc:has_service ?svc .
        ?svc svc:service_endpoint ?endp .
        ?svc svc:service_protocol ?proto .
      }
order by ?proto

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against a collection of gallery images.

Dump of all Data Space entries for a given ODS Photo Gallery including content and out-bound links

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>  
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#> 
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/> 
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
where {
        ?forum rdf:type sioct:ImageGallery .
        ?forum sioc:id ?forum_name.
        ?forum sioc:container_of ?post .
        optional {?post  dct:title ?title}.
        optional {?post dcc:created ?cr}.
        optional {?post sioc:link ?link} .
        optional {?post sioc:links_to ?links_to} .  
        optional {?post sioc:content ?content}
      }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of published Photos.

Community (Group Mode) Applications Data Space

ODS-Community and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioc:Community
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioc:Community
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/community/demoCommunity#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_creator
   * id
   * link
   * links_to
   * topic (tags) 
   * has_reply (TBD)
   * reply_of  (TBD)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum rdf:type sioc:Community .
        ?forum sioc:has_part ?parentf .
        ?parentf sioc:container_of ?post .
        ?post ?attribute ?o
      }
order by ?attribute

Dump of all Data Space entries for a given ODS Community

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix dct: <http://purl.org/dc/elements/1.1/>
select ?post ?title
where 
  {
    ?forum rdf:type sioc:Community .
    ?forum sioc:has_part ?parentf .
    ?parentf sioc:container_of ?post .
    optional{?post  dct:title ?title} .
  }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of Community Posts.

Briefcase Applications Data Space

ODS-Briefcase and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:Briefcase
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:Briefcase
Data Space Instance Identifier (URI)	ID	"<http://demo.openlinksw.com/dataspace/demo/briefcase/demoBriefcase#id>"

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content ( supported for file types: 'text/*');
   * has_container
   * has_creator
   * id
   * link
   * links_to ( supported for file types: 'text/html');
   * topic (tags) 

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where 
  {
    ?forum rdf:type sioct:Briefcase .
    ?forum sioc:container_of ?post .
    ?post ?attribute ?o  
  }
order by ?attribute

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Briefcase Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto 
where {
        ?forum a sioct:Briefcase .
        ?forum svc:has_service ?svc .
        ?svc svc:service_endpoint ?endp .
        ?svc svc:service_protocol ?proto .
      }
order by ?proto

Dump of all Briefcase Items from special "Public" folder

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select DISTINCT ?forum_name, ?post, ?title, ?cr, ?url, ?links_to
where    {
           ?forum a sioct:Briefcase .
           ?forum sioc:id ?forum_name.
           ?forum sioc:container_of ?post.
           optional { ?post dct:title ?title }.
           optional { ?post dcc:created ?cr }.
           optional { ?post sioc:link ?url }.
           optional { ?post sioc:links_to ?links_to }.
         }
order by DESC (?cr)

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against a collection of Feed Subscriptions.

Discussion / Conversation Data Space

Each Wiki, Weblog, Feed Manager, Bookmark Manager, Mail, and Photo Gallery, application instance with "Conversation" functionality enabled results in the generation of SIOC instance data from the ODS Discussion Application. For example, in the Weblog Data Space this implies that all comments are delegated to the Discussion Data Space application (which is an application of Virtuoso's NNTP engine) and exposed as SIOC data automatically.

ODS-Discussion and SIOC Ontology

ODS	SIOC	Sample Value
Data Space Class	Class	sioc:Container
Data Space SubClass	SubClass	sioct:MessageBoard
Data Space Generic Instance	Type	sioc:Container
Data Space Type Specific Instance	Type	sioct:MessageBoard

Data Space Post/Entry/Item Properties (sioc:Post predicates)

   * content
   * has_container
   * has_reply
   * id
   * link
   * links_to
   * reply_of
   * topic (tags) (TBD)  
   * has_creator: if the creator is not known, the foaf:maker is filled in

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
where {
        ?forum rdf:type sioct:MessageBoard .
        ?forum sioc:container_of ?post .
        ?post ?attribute ?o  
      }
order by ?attribute

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#> 
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
where {
        ?forum a sioct:MessageBoard ;
               sioc:id ?forum_name. 
        optional{ ?forum sioc:container_of ?post  } .
        optional{ ?post dct:title ?title } .
        optional{ ?post dcc:modified ?mod_time } .
        optional{ ?post dcc:created ?create_time } .
        optional{ ?post sioc:link ?url } .
      }

Obtaining a dump of all Posts within a specific ODS-Discussion Data Space that includes discussion content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url, ?content
where {
        ?forum a sioct:MessageBoard ;
                    sioc:id ?forum_name FILTER REGEX(?forum_name,".*demo*."). 
        optional{ ?forum sioc:container_of ?post  } .
        optional{ ?post dct:title ?title } .
        optional{ ?post dcc:modified ?mod_time } .
        optional{ ?post dcc:created ?create_time } .
        optional{ ?post sioc:link ?url } .
        optional{ ?post sioc:content ?content}.
      }

Sample Data (Live Query Results)

• Click Here for a live SPARQL Query (via SPARQL Protocol) against an ODS Discussion Data Space.

Dump of Blog Posts with "Conversation" Feature Enabled

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
where {
        ?forum rdf:type sioct:MessageBoard.
        optional{ ?forum sioc:id ?forum_name. FILTER REGEX(?forum_name,".*demo*.") }.
        optional{ ?forum sioc:container_of ?post  } .
        optional{ ?post dct:title ?title } .
        optional{ ?post dcc:modified ?mod_time } .
        optional{ ?post dcc:created ?create_time } .
        optional{ ?post sioc:link ?url } .
      }

Sample Data (Live Query Results)

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) against an ODS Discussion Data Space

Dump of Wiki Posts with "Conversation" Feature Enabled

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
where {
        ?forum rdf:type sioct:MessageBoard ;
               sioc:id ?forum_name FILTER REGEX(?forum_name,".*mywiki*.").
        optional{ ?forum sioc:container_of ?post  } .
        optional{ ?post dct:title ?title } .
        optional{ ?post dcc:modified ?mod_time } .
        optional{ ?post dcc:created ?create_time } .
        optional{ ?post sioc:link ?url } .
      }

Sample Data (Live Query Results)

• Click *Here* a live SPARQL Query (via SPARQL Protocol) against an ODS Discussion Data Space specifically scoped to discussions associated with a named Wiki: mywiki

Generic Data Space Queries

These SPARQL queries join data across serveral ODS data spaces.

Data for analyzing Tags associated with Posts that also demonstrates the use of the SKOS ontology for describing Post topics (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dc: <http://purl.org/dc/elements/1.1/>
select ?title, ?tag, ?topic 
where  
  {
    ?s a sioc:Item. 
    optional { ?s dc:title ?title }.
    ?s sioc:id ?id .
    optional { ?s sioc:topic ?topic .
                   ?topic rdf:type skos:Concept .
                   ?topic skos:prefLabel ?tag }
  }

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) version of this query.

People Network Construction that integrates data from both the FOAF and SKOS ontologies

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select DISTINCT ?forum_name, ?post, ?title, ?cr, ?url, ?links_to, ?tag, ?nick, ?gender, ?org, ?geodata
where    {
           ?forum a sioct:Weblog .
           ?forum sioc:id ?forum_name.
           optional {?forum sioc:scope_of ?role } . 
           optional { ?role sioc:function_of "<http://demo.openlinksw.com/dataspace/demo#this>" } . 
           ?forum sioc:container_of ?post.
           optional { ?post dct:title ?title.
                          ?post dcc:created ?cr.
                          ?post sioc:link ?url.
                          ?post sioc:links_to ?links_to.
                          ?post foaf:maker ?maker } .
           optional { ?maker foaf:nick ?nick  } .
           optional { ?maker foaf:name ?fname } . 
           optional { ?maker foaf:gender ?gender } . 
           optional { ?maker foaf:based_near ?geodata } . 
           optional { ?maker foaf:organization ?org } . 
           optional {?post sioc:topic ?topic . 
                        ?topic rdf:type skos:Concept . 
                        ?topic skos:prefLabel ?tag }
         }

• Click *Here* for a live SPARQL Query (via SPARQL Protocol) version of this query.

People Network Construction using data from Post Comments

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix xsd:   <http://www.w3.org/2001/XMLSchema#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
select DISTINCT ?post, ?post_sioc, ?post_author, ?post_title, ?post_date, ?reply
where {
    ?post sioc:has_creator ?_x .
    ?_x sioc:id ?post_author .
    optional { ?post rdfs:seeAlso ?post_sioc } .
    optional { ?post sioc:has_reply ?reply } .
    optional { ?post dcterms:created ?post_date } .
    optional { ?post dc:title ?post_title }
}

Click Here for a live SPARQL Query (via SPARQL Protocol) version of this query.

Using SPARQL CONSTRUCT to Export SIOC based RDF Data Sets

CONSTRUCT based SPARQL queries are very useful when trying to expose RDF (via a SPARQL Endpoint) to RDF Data Set consumers that do not support SPARQL. In a sense, the SPARQL CONSTRUCT statements as part of a SPARQL Protocol payload deliver a Data Web (Web 3.0) Experience to Interactive-Web Clients (Web 1.0).

People Network returned as an RDF Graph

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix xsd:   <http://www.w3.org/2001/XMLSchema#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>

CONSTRUCT
{
 ?post sioc:has_creator ?_x .
 ?_x sioc:id ?post_author .
 ?post rdfs:seeAlso ?post_sioc .
 ?post sioc:has_reply ?reply .
 ?post dcterms:created ?post_date .
 ?post dc:title ?post_title .
}
where {
    ?post sioc:has_creator ?_x .
    ?_x sioc:id ?post_author .
    optional{ ?post rdfs:seeAlso ?post_sioc } .
    optional{ ?post sioc:has_reply ?reply } .
    optional{ ?post dcterms:created ?post_date } .
    optional{ ?post dc:title ?post_title }
}

Discussions posts details returned as an RDF Graph

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
{
?post dcterms:created ?created .
?post sioc:link ?link .
?post sioc:title ?title .
}
where
  {
    ?forum a sioct:MessageBoard .
    ?post sioc:has_container ?forum .
    optional { ?post dcterms:created ?created } .
    optional { ?post sioc:link ?link } .
    optional { ?post sioc:title ?title }
  }

List of all registered Dataspace members's home pages URLs returned as an RDF Graph

prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
CONSTRUCT
{
 ?x rdf:type sioc:User . 
}
where
{
  ?x rdf:type sioc:User . 
}

Gallery images details for user "demo" returned as an RDF Graph

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>  
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
{
  ?post dc:title ?title .
  ?post sioc:link ?link .
  ?post sioc:links_to ?links_to .
  ?post sioc:topic ?topic .
  ?post dcterms:created ?cr 
}
where 
{
  ?post rdf:type sioc:Item .
  optional { ?post dc:title ?title } .
  optional { ?post sioc:link ?link } . 
  optional { ?post sioc:links_to ?links_to } .
  optional { ?post dcterms:created ?cr } .
  optional { ?post sioc:topic ?topic }.
  optional { ?topic skos:prefLabel ?tag }.
  ?post sioc:has_container ?forum .
  ?forum a sioct:ImageGallery  .
  ?forum sioc:scope_of ?role. 
  ?role sioc:function_of ?member.
  ?member sioc:id "demo" 
}

Community posts title and date details returned as an RDF Graph

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
{
  ?post dc:title ?title .
  ?post dcterms:created ?date 
}
where 
{
  ?forum rdf:type sioc:Community .
  ?forum sioc:has_part ?parentf .
  ?parentf sioc:container_of ?post .
  optional { ?post dc:title ?title } .
  optional { ?post dcterms:created ?date } .
}

References

Learn More

• Query ODS Data Spaces using SPARQL and Atom OWL Ontology
• Query ODS Data Spaces using SPARQL and SKOS Ontology
• Query ODS Data Spaces using SPARQL and FOAF Ontology
• Query ODS Data Spaces using SPARQL and Annotea Ontology
• ODS SPARQL Samples
• Northwind SPARQL Reference
• Query Virtuoso Tutorials using SPARQL
• Query Virtuoso Documentation using SPARQL
• WordPress SIOC Reference
• MedaWiki SIOC Reference
• PHPBB SIOC Reference
• Drupal SIOC Reference

Specs

• SPARQL - Query Language
• SPARQL - Protocol
• SPARQL - XML based Results Format

FAQs

• SPARQL FAQ - Lee Feigenbaum

Presentations

• SPARQL Introduction - Dave Beckett, XTech 2004
• SPARQL Introduction - Dave Beckett, Standford University Presentation
• SPARQL Query Protocol presentation at XTech 2006 by Leigh Dodds
• SPASQL - Initiative to add SPARQL to MySQL

Tutorials

• SPARQL Tutorial - Clark+Prasia & University of Manchester Tutorial
• Jena SPARQL Tutorial